new file mode 100644
@@ -0,0 +1,6 @@
+# This software is a part of ISAR.
+# Copyright (C) 2025 Siemens
+
+require conf/machine/rpi-arm64-v8-efi.inc
+
+IMAGER_INSTALL:wic += "${SYSTEMD_BOOTLOADER_INSTALL}"
new file mode 100644
@@ -0,0 +1,22 @@
+# This software is a part of ISAR.
+# Copyright (C) 2025 Siemens
+
+DISTRO_ARCH ?= "arm64"
+KERNEL_NAME ?= "arm64"
+
+IMAGE_FSTYPES ?= "wic"
+WKS_FILE ?= "rpi-arm64-v8-efi.wks"
+
+IMAGER_BUILD_DEPS = "bootconfig-rpi-efi"
+IMAGER_INSTALL:wic += "${IMAGER_BUILD_DEPS}"
+
+IMAGE_EFI_BOOT_FILES = " \
+ /usr/lib/bootconfig-rpi-efi/config.txt;config.txt \
+ /usr/lib/u-boot/rpi_arm64/u-boot.bin;u-boot.bin \
+ /usr/lib/rpi-firmware/fixup4.dat;fixup4.dat \
+ /usr/lib/rpi-firmware/start4.elf;start4.elf \
+ /usr/lib/rpi-firmware/overlays/*;overlays/ \
+ ${IMAGE_ROOTFS}/usr/lib/linux-image-*/broadcom/bcm2711-rpi-4*.dtb \
+"
+
+IMAGE_PREINSTALL:append = " firmware-brcm80211"
@@ -61,6 +61,7 @@ BBMULTICONFIG = " \
rpi-arm-v7l-bookworm \
rpi-arm64-v8-bullseye \
rpi-arm64-v8-bookworm \
+ rpi-arm64-v8-efi-bookworm \
sifive-fu540-trixie \
starfive-visionfive2-trixie \
qemuarm64-focal \
new file mode 100644
@@ -0,0 +1,5 @@
+# This software is a part of Isar.
+# Copyright (C) 2025 Siemens
+
+MACHINE ?= "rpi-arm64-v8-efi"
+DISTRO ?= "debian-bookworm"
new file mode 100644
@@ -0,0 +1,19 @@
+# This software is a part of ISAR.
+# Copyright (C) 2025 Siemens
+
+inherit dpkg-raw
+
+SRC_URI = "file://config.txt"
+
+DESCRIPTION = "Raspberry Pi config to boot using U-Boot EFI"
+MAINTAINER = "isar-users <isar-users@googlegroups.com>"
+
+DPKG_ARCH = "arm64"
+DEBIAN_DEPENDS = "firmware-rpi, u-boot-rpi"
+RDEPENDS:${PN} += "firmware-rpi"
+
+do_install[cleandirs] += "${D}/usr/lib/${BPN}"
+do_install() {
+ DST=${D}/usr/lib/${BPN}
+ install -m 0644 ${WORKDIR}/config.txt $DST
+}
new file mode 100644
@@ -0,0 +1,9 @@
+arm_64bit=1
+arm_boost=1
+enable_uart=1
+uart_2ndstage=1
+disable_commandline_tags=1
+kernel=u-boot.bin
+
+[pi4]
+max_framebuffers=2
new file mode 100644
@@ -0,0 +1,5 @@
+boot/bootcode.bin usr/lib/rpi-firmware
+boot/LICENCE.broadcom usr/lib/rpi-firmware
+boot/*.dat usr/lib/rpi-firmware
+boot/*.dtb usr/lib/rpi-firmware
+boot/*.elf usr/lib/rpi-firmware
new file mode 100644
@@ -0,0 +1,7 @@
+#!/usr/bin/make -f
+
+%:
+ dh $@
+
+override_dh_strip:
+override_dh_dwz:
new file mode 100644
@@ -0,0 +1,22 @@
+# This software is a part of ISAR.
+# Copyright (C) 2025 Siemens
+
+inherit dpkg
+
+DESCRIPTION = "Raspberry Pi firmware blobs"
+MAINTAINER = "isar-users <isar-users@googlegroups.com>"
+
+SRC_URI = " \
+ https://github.com/raspberrypi/firmware/archive/${PV}.tar.gz;downloadfilename=${PN}-${PV}.tar.gz \
+ file://debian/install \
+ file://debian/rules \
+"
+SRC_URI[sha256sum] = "4981021b82f600f450d64d9b82034dc603bf5429889a3947b2863e01992a343c"
+
+S = "${WORKDIR}/firmware-${PV}"
+
+do_prepare_build[cleandirs] += "${S}/debian"
+do_prepare_build() {
+ deb_debianize
+ cp -r ${WORKDIR}/debian ${S}
+}
new file mode 100644
@@ -0,0 +1,4 @@
+part /boot --source bootimg-efi-isar --use-uuid --sourceparams "loader=systemd-boot" --label efi --part-type EF00 --align 8192 --size 256M
+part / --source rootfs --use-uuid --fstype ext4 --mkfs-extraopts "-T default" --label platform --align 8192 --exclude-path boot/ --extra-space 1G
+
+bootloader --ptable gpt --timeout 3 --append "rootwait console=ttyS1,115200 module_blacklist=vc4"
Booting the RPI via EFI makes it much easier to decouple the image contents, firmware, boot config and kernel cmdline. For that, we add a new target rpi-arm64-v8-efi that boots the RPI using u-boot efi. We further switch that target to debian bookworm (instead of raspios bookworm) and by that have a baseline that is closer to upstream. The recipes are written in a way to make it easy to customize in downstream layers and only carry a bare minimum of configuration. Signed-off-by: Felix Moessbauer <felix.moessbauer@siemens.com> --- meta-isar/conf/machine/rpi-arm64-v8-efi.conf | 6 +++++ meta-isar/conf/machine/rpi-arm64-v8-efi.inc | 22 +++++++++++++++++++ meta-isar/conf/mc.conf | 1 + .../rpi-arm64-v8-efi-bookworm.conf | 5 +++++ .../bootconfig-rpi-efi/bootconfig-rpi-efi.bb | 19 ++++++++++++++++ .../bootconfig-rpi-efi/files/config.txt | 9 ++++++++ .../firmware-rpi/files/debian/install | 5 +++++ .../firmware-rpi/files/debian/rules | 7 ++++++ .../firmware-rpi/firmware-rpi_1.20250305.bb | 22 +++++++++++++++++++ .../lib/wic/canned-wks/rpi-arm64-v8-efi.wks | 4 ++++ 10 files changed, 100 insertions(+) create mode 100644 meta-isar/conf/machine/rpi-arm64-v8-efi.conf create mode 100644 meta-isar/conf/machine/rpi-arm64-v8-efi.inc create mode 100644 meta-isar/conf/multiconfig/rpi-arm64-v8-efi-bookworm.conf create mode 100644 meta-isar/recipes-bsp/bootconfig-rpi-efi/bootconfig-rpi-efi.bb create mode 100644 meta-isar/recipes-bsp/bootconfig-rpi-efi/files/config.txt create mode 100644 meta-isar/recipes-bsp/firmware-rpi/files/debian/install create mode 100644 meta-isar/recipes-bsp/firmware-rpi/files/debian/rules create mode 100644 meta-isar/recipes-bsp/firmware-rpi/firmware-rpi_1.20250305.bb create mode 100644 meta-isar/scripts/lib/wic/canned-wks/rpi-arm64-v8-efi.wks